echo off
title BartPE USB Installer for USB HDD like install (minint and programs)
echo.
echo BartPE USB Installer v1.0.1.1 UPDATED for HDD like install
echo Copyright (c) 2005 Bart Lagerweij. All rights reserved.
echo This program is free software. Use and/or distribute it under
echo the terms of the Nu2 License.
echo.
echo Updated by fafot for USB - HDD like install (minint and programs) (not for ISO)
echo.
setlocal
set _format=
set _target=
set _base=%~dp0
if "%1" == "-f" set _format=1& shift
set _target=%~d1
echo %_target%
echo %_base%
if "%_target%" == "" (
    echo Usage pe2usb [-f] ^<drive:^>
    echo.
    echo Where:
    echo     ^<drive:^> The drive letter of your USB flash drive
    echo     -f       Format USB drive and install patched bootsector
    echo              ^(this is only needed the first time^)
    goto _err)
echo USB target drive set to "%_target%"
echo Checking drive "%_target%"
if not exist %_target%\nul (
    echo Error: Drive "%_target%" does not exist!
    goto _err)
if "%_target%" == "%SystemDrive%" (
    echo Error: Trying to install to your SystemDrive?!?
    goto _err)
echo Checking files...
for %%i in (%_base%plugin\peinst\mkbt.exe %_base%srsp1\ramdisk.sys %_base%srsp1\setupldr.bin) do if not exist "%%i" (
    echo Error: File %%i not found!
    echo Please check the pe2usb.txt for details!
    goto _err)
if not "%_format%" == "1" goto _install
echo.
echo *******************************************************************************
echo Drive %_target% will be formatted!!! All data on drive will be erased!
echo *******************************************************************************
echo.
set /p _answer=Type "YES" (uppercase) to continue:
if "%_answer%" == "YES" goto _format
echo You type "%_answer%", format aborted...
goto _err
:_format
echo Formating drive "%_target%"...

%_base%srsp1\HPUSBFW.EXE %_target%
if errorlevel 1 (
    echo Error: Format %_target% failed!
    goto _err)

:_install
:: Finding sourcs directory
FOR /f "tokens=1* delims== skip=1 eol=;" %%a IN (%_base%input.inf) DO IF "%%a"=="fulloutdir" SET _source=%%b
echo Source directory from input.inf: %_source%


echo Checking bootsector from drive %_target%
%_base%plugin\peinst\mkbt.exe -x -i %_target%
if errorlevel 1 (
    echo Error: Boot sector inspection failed!
    goto _err)
echo Copying %_base%srsp1\ramdisk.sys to %_source%i386\system32\drivers
copy /y %_base%srsp1\ramdisk.sys %_source%i386\system32\drivers
if errorlevel 1 (
    echo Error: copy %_base%srsp1\ramdisk.sys to %_source%i386\system32\drivers failed!
    goto _err)
echo Copying %_base%srsp1\setupldr.bin to %_target%\ntldr
copy /y %_base%srsp1\setupldr.bin %_target%\ntldr
if errorlevel 1 (
    echo Error: copy %_base%srsp1\setupldr.bin to %_target%\ntldr failed!
    goto _err)
echo Copying %_source%i386\ntdetect.com to %_target%\
copy /y %_source%i386\ntdetect.com %_target%\
if errorlevel 1 (
    echo Error: copy %_source%i386\ntdetect.com to %_target%\ failed!
    goto _err)

:: Copy I386 and Programs
echo Copying %_source%i386 to %_target%\minint
call :_copy i386 minint
if errorlevel 1 goto _err
echo Copying %_source%programs to %_target%\programs
call :_copy programs programs
if errorlevel 1 goto _err
goto _done

:_copy
if "%~1" == "" goto :eof
if "%~2" == "" goto :eof
if not exist "%_source%\%~1" goto :eof
if exist "%_target%\%~2" (
    echo pe2USB-FULL: Checking for BartPE tag file ^(save removal^)...
    if not exist "%_target%\%~2\bartpe.tag" goto _tagErr
    echo pe2USB-FULL: Removing %_target%\%~2
    rmdir /s /q "%_target%\%~2\")
    if errorlevel 1 goto :eof
    mkdir "%_target%\%~2\"
    if errorlevel 1 goto :eof
    echo pe2USB-FULL: Tag file for BartPE do not remove! > "%_target%\%~2\bartpe.tag"
    if errorlevel 1 goto :eof
echo pe2USB-FULL: Copying files from "%_source%\%~1" to "%_target%\%~2"
xcopy /e /s "%_source%\%~1\*.*" "%_target%\%~2\"
goto :eof
:_tagErr
echo pe2USB-FULL: Tag file "%_target%\%~2\bartpe.tag" not found!
echo pe2USB-FULL: Not safe to remove directory!
echo.
echo pe2USB-FULL: Workaround:
echo pe2USB-FULL: You could delete the folder "%_target%\%~2" manually and restart the installation...
rem set errorlevel to 1 by (mis)using color
color 00
goto _end

:_done
echo.
echo Ready!
echo.
goto _end

:_err
echo.
echo Aborted...
echo There was an error, script aborted!!!
rem set errorlevel to 1 by (mis)using color
color 00

:_end
endlocal
echo.
echo Done (program will be closed)
pause
exit